# Bureau Cinnamon générique pour la flotte. Adapté (pas importé) depuis
# nixos_cinnamon/hosts/cinnamon/desktop-cinnamon.nix : les deux repos
# restent indépendants au `git pull`.
{ pkgs, ... }:

{
  services.xserver.enable = true;
  services.xserver.displayManager.lightdm.enable = true;
  services.xserver.displayManager.lightdm.background = "/etc/nixos/hosts/common/wallpaper/Nix/13977413.png";
  services.xserver.desktopManager.cinnamon.enable = true;
  services.accounts-daemon.enable = true;

  environment.cinnamon.excludePackages = with pkgs; [
    celluloid
    warpinator
  ];

  # Fond d'écran par défaut (juste le logo NixOS, pas la galerie perso de
  # nixos_cinnamon -- repo public, on n'y met que ce qui est nécessaire).
  # Ce chemin (/etc/nixos) suppose la config installée là -- voir
  # nixos_fleet/installer/install.sh (do_install copie le clone sur le
  # disque cible après nixos-install).
  environment.etc."dconf/db/local.d/00-background".text = ''
    [org/cinnamon/desktop/background]
    picture-uri='file:///etc/nixos/hosts/common/wallpaper/Nix/13977413.png'
  '';
  system.activationScripts.dconfUpdate.text = "${pkgs.dconf}/bin/dconf update";

  # Réglages de confidentialité génériques (pas de SearXNG/DNS personnels
  # comme sur le poste perso — cette config est destinée à être publique).
  programs.firefox = {
    enable = true;
    languagePacks = [ "fr" ];

    preferences = {
      "privacy.resistFingerprinting" = true;
      "browser.newtabpage.activity-stream.showSponsored" = false;
      "browser.search.suggest.enabled" = false;
      "dom.security.https_only_mode" = true;
      "media.peerconnection.enabled" = false;
      "geo.enabled" = false;
      "network.captive-portal-service.enabled" = false;
    };

    policies = {
      DisableTelemetry = true;
      DisablePocket = true;
      DisableFirefoxStudies = true;
      OfferToSaveLogins = false;
      DontCheckDefaultBrowser = true;
      EnableTrackingProtection = {
        Value = true;
        Locked = true;
      };
      ExtensionSettings = {
        "uBlock0@raymondhill.net" = {
          install_url = "https://addons.mozilla.org/firefox/downloads/latest/ublock-origin/latest.xpi";
          installation_mode = "force_installed";
        };
      };
    };
  };

  environment.systemPackages = with pkgs; [
    libreoffice
    thunderbird
    vlc
  ];
}