Nixos_Fleet/hosts/common/desktop.nix

# Bureau Cinnamon générique pour la flotte. Adapté (pas importé) depuis
# nixos_cinnamon/hosts/cinnamon/desktop-cinnamon.nix : les deux repos
# restent indépendants au `git pull`.
{ pkgs, ... }:

{
  services.xserver.enable = true;
  services.xserver.displayManager.lightdm.enable = true;
  services.xserver.displayManager.lightdm.background = "/etc/nixos/hosts/common/wallpaper/Nix/13977413.png";
  services.xserver.desktopManager.cinnamon.enable = true;
  services.accounts-daemon.enable = true;

  environment.cinnamon.excludePackages = with pkgs; [
    celluloid
    warpinator
  ];

  # Fond d'écran par défaut (logo NixOS, pas la galerie perso de
  # nixos_cinnamon). Suppose la config installée sur /etc/nixos (voir
  # installer/install.sh).
  environment.etc."dconf/db/local.d/00-background".text = ''
    [org/cinnamon/desktop/background]
    picture-uri='file:///etc/nixos/hosts/common/wallpaper/Nix/13977413.png'
  '';
  system.activationScripts.dconfUpdate.text = "${pkgs.dconf}/bin/dconf update";

  # Confidentialité générique (pas de SearXNG/DNS perso : repo public).
  programs.firefox = {
    enable = true;
    languagePacks = [ "fr" ];

    preferences = {
      "privacy.resistFingerprinting" = true;
      "browser.newtabpage.activity-stream.showSponsored" = false;
      "browser.search.suggest.enabled" = false;
      "dom.security.https_only_mode" = true;
      "media.peerconnection.enabled" = false;
      "geo.enabled" = false;
      "network.captive-portal-service.enabled" = false;
      # Do Not Track : plus d'UI depuis les versions récentes de Firefox,
      # mais le pref existe encore et envoie bien l'en-tête DNT=1.
      "privacy.donottrackheader.enabled" = true;
    };

    policies = {
      DisableTelemetry = true;
      DisablePocket = true;
      DisableFirefoxStudies = true;
      OfferToSaveLogins = false;
      DontCheckDefaultBrowser = true;
      EnableTrackingProtection = {
        Value = true;
        Locked = true;
      };

      # DuckDuckGo est un moteur intégré à Firefox, pas besoin de l'Add.
      SearchEngines.Default = "DuckDuckGo";

      # Pubs/contenu sponsorisé sur le nouvel onglet et la barre d'adresse.
      FirefoxHome = {
        SponsoredTopSites = false;
        SponsoredPocket = false;
        Locked = true;
      };
      FirefoxSuggest.SponsoredSuggestions = false;

      ExtensionSettings = {
        "uBlock0@raymondhill.net" = {
          install_url = "https://addons.mozilla.org/firefox/downloads/latest/ublock-origin/latest.xpi";
          installation_mode = "force_installed";
        };
        "jid1-MnnxcxisBPnSXQ@jetpack" = {
          install_url = "https://addons.mozilla.org/firefox/downloads/latest/privacy-badger17/latest.xpi";
          installation_mode = "force_installed";
        };
      };
    };
  };

  environment.systemPackages = with pkgs; [
    # === Office/Notes ===
    libreoffice
    pdfarranger
    simple-scan

    # === System tools ===
    btop
    unzip
    screenfetch
    tmux
    fwupd
    fwupd-efi
    ncdu
    gdu
    hplip
    gutenprint
    cups
    inxi
    ntfs3g

    # === Communication/Media ===
    thunderbird
    ffmpeg
    vlc
    mpv
    strawberry
  ];

  # Flatpak
  services.flatpak.enable = true;
  xdg.portal.enable = true;
  xdg.portal.extraPortals = [ pkgs.xdg-desktop-portal-gtk ];

  systemd.services.flatpak-repo = {
    wantedBy = [ "multi-user.target" ];
    after = [ "network-online.target" ];
    wants = [ "network-online.target" ];
    serviceConfig = {
      Type = "oneshot";
      RemainAfterExit = true;
    };
    path = [ pkgs.flatpak ];
    script = ''
      flatpak remote-add --if-not-exists flathub \
        https://dl.flathub.org/repo/flathub.flatpakrepo
    '';
  };

  systemd.services.flatpak-install = {
    wantedBy = [ "multi-user.target" ];
    after = [
      "flatpak-repo.service"
      "network-online.target"
    ];
    wants = [ "network-online.target" ];
    requires = [ "flatpak-repo.service" ];
    serviceConfig = {
      Type = "oneshot";
      RemainAfterExit = true;
    };
    path = [ pkgs.flatpak ];
    script = ''
      flatpak install -y flathub \
      net.waterfox.waterfox \
       eu.betterbird.Betterbird
    '';
  };

  systemd.services.flatpak-update = {
    wantedBy = [ "multi-user.target" ];
    path = [ pkgs.flatpak ];
    script = ''
      flatpak update -y
    '';
  };

  programs.appimage = {
    enable = true;
    binfmt = true;
  };
}